Did not work either. Here is the code that I think controls the banning in EVO mod maybe you can examine it and see if there is a conflict? Or maybe we can change it to work with your coding?:
//
// Evo MOD .chat command parser
//
function EvoConsoleParseHelp( %sender )
{
messageClient( %sender, "EvoCon",
"\c2Evo Console Commands:\n" @
".help\n" @
".motd\n" @
".cp <text>\n" @
".bottomprint <on|off>\n" @
"- - - - - - - - - - - - - -\n" );
messageClient( %sender, "EvoCon",
"\c2.login <passwd>\n" @
".logout\n" @
".claimLease\n" @
".joinpw <passwd>\n" @
"- - - - - - - - - - - - - -\n" );
messageClient( %sender, "EvoCon",
"\c2.wonid <name|wonid|plyrid>\n" @
".whois <name|wonid|plyrid>\n" @
".warn <name|wonid|plyrid>\n" @
".kick <name|wonid|plyrid>\n" @
".ban <name|wonid|plyrid>\n" @
"- - - - - - - - - - - - - -\n" );
messageClient( %sender, "EvoCon",
"\c2.teamname <nr> <name>\n" @
".teamname reset\n" @
".clanlock <nr> <name>\n" @
".clanlock remove\n" @
"- - - - - - - - - - - - - -\n" @
".nbr <on|off|players>\n" );
}
function EvoConsoleMOTD( %sender )
{
if ( $Host::EvoMOTD !$= "" )
{
centerprint(%sender, $Host::EvoMOTD, $Host::EvoMOTDtime, $Host::EvoMOTDlines);
}
else
{
messageClient(%sender, "EvoConErr", "\c2This server does not have a MOTD." );
}
return;
}
function EvoConsoleToggleBottomPrint( %sender, %value )
{
switch$(%value)
{
case "on" :
serverCMDToggleBottomPrint( %sender, 1 );
messageClient( %sender, "EvoCon", "Bottomprint messages turned on." );
case "off" :
serverCMDToggleBottomPrint( %sender, 0 );
messageClient( %sender, "EvoCon", "Bottomprint messages turned off." );
default:
messageClient( %sender, "EvoCon", "Usage: .bottomprint <on|off>" );
}
return;
}
function EvoConsoleCenterPrint ( %sender, %text )
{
if ( !%sender.isAdmin && !%sender.isSuperAdmin )
{
messageClient( %sender, "EvoConErr", "\c2Only Admins and Super Admins can use this command." );
return;
}
centerPrintAll( getTaggedString( %sender.name ) @ " - " @ %text, 5, 1 );
}
function EvoConsoleMyWonID( %sender )
{
messageClient( %sender, "EvoCon", "Your WonID is " @ %sender.guid @"." );
return;
}
function EvoConsoleSetJoinPass( %sender, %password )
{
serverCmdSADSetPassword(%sender, %password);
return;
}
function EvoConsoleLogin( %sender, %password )
{
serverCmdSAD( %sender, %password );
return;
}
function EvoConsoleClaimSA ( %sender )
{
messageClient( %sender, 'EvoConErr', 'Note: This command is obsolete. Please use .claimLease instead.' );
}
function EvoConsoleClaimLease ( %sender )
{
// Super Admins do not need to claim a lease. They cannot benefit from it
// anyway.
if ( %sender.isSuperAdmin )
{
messageClient( %sender, 'EvoConErr', 'You already are SuperAdmin.' );
return;
}
// Get the lease information
%LeaseLevel = EvoCurrentLease ( %sender.guid );
// If lease is not found, return with error
if ( %LeaseLevel == 0 )
{
messageClient( %sender, "EvoConErr", "You cannot claim Admin status. No lease has been registered for your WonID." );
return;
}
if ( %LeaseLevel == 1 )
{
if ( %client.isAdmin )
{
messageClient( %sender, 'EvoConErr', 'Your lease is for admin status which you already have.' );
return;
}
%sender.isAdmin = 1;
%sender.isSuperAdmin = 0;
messageAll('MsgAdminPlayer', '\c3%2 \c2has claimed his leased Admin status.', %sender, %sender.name );
%adminmsg = " has claimed his leased Admin status.";
}
else // LeaseLevel > 1
{
%sender.isAdmin = 1;
%sender.isSuperAdmin = 1;
messageAll('MsgSuperAdminPlayer', '\c3%2 \c2has claimed his leased SuperAdmin status.', %sender, %sender.name );
%adminmsg = " has claimed his leased SA status.";
}
if ( %sender.pizza )
{
pizzaSendHudUpdate( %game, %sender, "" );
}
adminLog(%sender, %adminmsg);
logEcho(%sender.nameBase @ %adminmsg );
return;
}
// EvoCommandWhois(%sender, %param)
// Info: do a whois on a player
function EvoConsoleWhois(%sender, %param)
{
if (! ( ( %sender.isAdmin && $Host::EvoAdminWhois ) ||
( %sender.isSuperAdmin && $Host::EvoSuperAdminWhois ) )
)
{
messageClient(%sender, 'EvoConErr', '\c2This command is disabled for your admin level.');
return;
}
%target = EvoFindTarget(%param);
if(%target == -1)
messageClient(%sender, 'EvoCon', '\c2.whois usage: .whois <name|id|guid>');
else
{
if( %target.isSuperAdmin && $Host::EvoBlockSuperAdminWhois )
{
messageClient(%sender, 'EvoConErr', '\c2Whois disabled with Super Admins.');
return;
}
%authInfo = %target.getAuthInfo();
messageClient(%sender, 'EvoCon', '%1, REALNAME: %2, CLAN: %3, GUID: %4, CLIENT: %5, %6', %target.name, getField(%authInfo, 0), getField(%authInfo, 1), %target.guid, %target, %target.getAddress());
}
}
// EvoCommandWarnPlayer(%sender, %param)
// Info: warn a player
function EvoConsoleWarnPlayer(%sender, %param)
{
if(!%sender.isAdmin)
{
messageClient(%sender, 'EvoConErr', '\c2You must be an admin to use this command.');
return;
}
%target = EvoFindTarget(%param);
if(%target == %sender)
{
messageClient(%sender, 'EvoConErr', '\c2You can not warn yourself!');
return;
}
if(%target == -1)
messageClient(%sender, 'EvoCon', '\c2.warn usage: .warn <name|id|guid>');
else
serverCmdWarnPlayer(%sender, %target);
}
// EvoCommandKickPlayer(%sender, %param)
// Info: kick a player
function EvoConsoleKickPlayer(%sender, %param)
{
if(!%sender.isAdmin)
{
messageClient(%sender, 'EvoConErr', '\c2You must be an admin to use this command.');
return;
}
%target = EvoFindTarget(%param);
if(%target == %sender)
{
messageClient(%sender, 'EvoConErr', '\c2You can not kick yourself!');
return;
}
if(!%sender.isSuperAdmin && %target.isAdmin) // only super admins can kick admins
{
messageClient(%sender, 'EvoConErr', '\c2You can not kick %1, %2 is an Admin!', %target.name, %target.sex $= "Male" ? 'he' : 'she');
return;
}
if(%target == -1)
messageClient(%sender, 'EvoCon', '\c2.kick usage: .kick <name|id|guid>');
else
{
Game.kickClientName = %target.name;
kick(%target, %sender, %target.guid);
%authInfo = %target.getAuthInfo();
adminLog(%sender, " kicked " @ %target.nameBase @ "( " @ getField(%authInfo, 0) @ ", " @ getField(%authInfo, 1) @ ", " @ %target.guid @ ", " @ %target.getAddress() @ ")");
}
}
// EvoCommandBanPlayer(%sender, %param)
// Info: ban a player
function EvoConsoleBanPlayer(%sender, %param)
{
if ( $Host::TournamentMode )
{
mesageClient ( %sender, 'EvoConErr', '\c2This command is disabled in Tournament Mode.~wfx/misc/error.misc.wav');
return;
}
if(!%sender.isAdmin)
{
messageClient(%sender, 'EvoCoNErr', '\c2You must be an admin to use this command.');
return;
}
if(!%sender.isSuperAdmin && !$Host::EvoAdminBan)
{
messageClient(%sender, 'EvoConErr', '\c2This command is disabled for your admin level.');
return;
}
%target = EvoFindTarget(%param);
if(%target == %sender)
{
messageClient(%sender, 'EvoConErr', '\c2You can not ban yourself!');
return;
}
if(!%sender.isSuperAdmin && %target.isAdmin) // only super admins can ban admins
{
messageClient(%sender, 'EvoConErr', '\c2You can not ban %1, %2 is an Admin!', %target.name, %target.sex $= "Male" ? 'he' : 'she');
return;
}
if(%target == -1)
messageClient(%sender, 'EvoConErr', '\c2.ban usage: .ban <name|id|guid>');
else
{
ban(%target, %sender);
%authInfo = %target.getAuthInfo();
adminLog(%sender, " banned " @ %target.nameBase @ "( " @ getField(%authInfo, 0) @ ", " @ getField(%authInfo, 1) @ ", " @ %target.guid @ ", " @ %target.getAddress() @ ")");
}
}
function EvoConsoleClanLock ( %sender, %param )
{
if( ! ( ( %sender.isAdmin && $Host::EvoAdminClanLock ) ||
( %sender.isSuperAdmin && $Host::EvoSuperAdminClanLock ) )
)
{
messageClient(%sender, 'EvoConErr', '\c2You do not have the required privileges to use this command.~wfx/misc/error.misc.wav');
return;
}
%Team = firstWord( %param );
%Clan = restWords( %param );
if ( %Team $= "remove" )
{
$Evo::ThisMission::ClanLockActive = 0;
if ( $Evo::ThisMission::ClanLockTeam )
{
EvoRemoveTempTeamName( $Evo::ThisMission::ClanLockTeam );
}
messageAll ( 'EvoCon', '\c2Clanlock has been removed.~wfx/misc/diagnostic_on.wav' );
return;
}
if ( %Team != 1 && %Team != 2 )
{
messageClient( %sender, 'EvoConErr', 'Team must be either 1 or 2.' );
return;
}
if ( $Evo::ThisMission::ClanLockTeam )
{
EvoRemoveTempTeamName( $Evo::ThisMission::ClanLockTeam );
}
$Evo::ThisMission::ClanLockClan = %Clan;
$Evo::ThisMission::ClanLockTeam = %Team;
$Evo::ThisMission::ClanLockActive = 1;
messageAll( 'EvoCon', '\c2Team \c3%1\c2 has been locked. Only members of \c3%2\c2 are now allowed there.~wfx/misc/diagnostic_on.wav', Game.getTeamName(%Team), %Clan );
%NumPlayers = ClientGroup.getCount();
%OtherTeam = ( %Team == 1 ) ? 2 : 1;
for ( %Counter = 0; %Counter < %NumPlayers; %Counter ++ )
{
%Client = ClientGroup.getObject( %Counter );
if ( // ( !%Client.isAdmin ) &&
( %Client.team == %Team ) &&
( !EvoIsClientInClan( %Client, %Clan ) )
)
{
messageClient( %Client, 'EvoClanLock', '\c2Switching you to other team.' );
Game.clientChangeTeam( %Client, %OtherTeam, 0 );
}
}
// Set team name /after/ announcing the team lock only!
EvoSetTempTeamName(%Team, %Clan );
echo("Set Teamname. Now, getTeamName returns "@ Game.getTeamName(%Team) );
return;
}
function EvoConsoleNoBaseRape( %sender, %string )
{
if ( !%sender.isSuperAdmin )
{
messageClient( %sender, 'EvoConErr', '\c2Only SuperAdmins can use this command.' );
return;
}
if ( $Host::TournamentMode )
{
messageClient( %sender, 'EvoConErr', '\c2You cannot access the No Base Rape settings in Tournament Mode.' );
return;
}
if ( %string $= "off" )
{
serverCmdNBRSetup( %sender, "NoBaseRape", 0 );
return;
}
if ( %string $= "on" )
{
serverCmdNBRSetup( %sender, "NoBaseRape", 1 );
return;
}
if ( !isNumber( %string ))
{
messageClient( %sender, 'EvoConErr', '\c2Syntax: .nbr <on|off|number of players>' );
return;
}
serverCmdNBRSetup( %sender, "NoBaseRapeBase", %string );
return;
}
function EvoConsoleTeamName ( %sender, %string )
{
if ( !%sender.isSuperAdmin )
{
messageClient( %sender, 'EvoConErr', '\c2Only SuperAdmins can use this command.' );
return;
}
%Team = firstWord( %string );
%NewName = restWords( %string );
echo("Team : "@%Team@" Name : "@%NewName );
if ( %Team $= "reset" )
{
for ( %teamCount = 1; %teamcount <= Game.numteams; %teamcount++ )
{
EvoRemoveTempTeamName( %teamCount );
}
messageAll( '', '\c2The admin has reset all teamnames to their default values.' );
return;
}
if ( (!isNumber( %Team )) || ( %NewName $= "" ) )
{
messageClient(%sender, 'EvoConErr', '\c2Syntax: .teamname <team number> <new team name>' );
return;
}
messageAll( '', '\c2The admin has changed the name of team \c3%1\c2 from \c3%2\c2 to \c3%3\c2.', %Team, Game.getTeamName( %Team ), %NewName );
EvoSetTempTeamName( %Team, %NewName );
return;
}
function EvoParseCommands( %sender, %string )
{
// Remove leading and trailing spaces
%string = trim ( %string );
if ( strstr( %string, "%" ) == 0 )
// Allow abbreviated login command, Tricon2 Style
{
EvoConsoleLogin ( %sender, getSubStr( %string, 1, 255 ) );
return;
}
%Command = firstWord ( %string );
%Parameters = trim ( restWords ( %string ) );
switch$(%Command)
{
case ".help" : EvoConsoleParseHelp ( %sender );
case ".motd" : EvoConsoleMOTD ( %sender );
case ".wonid" : EvoConsoleMyWonID ( %sender );
case ".cp" : EvoConsoleCenterPrint ( %sender, %Parameters );
case ".joinpw" : EvoConsoleSetJoinPass ( %sender, %Parameters );
case ".login" : EvoConsoleLogin ( %sender, %Parameters );
case ".logout" : EvoConsoleLogin ( %sender, "logout" );
case ".bottomprint" : EvoConsoleToggleBottomPrint ( %sender, %Parameters );
case ".claimSA" : EvoConsoleClaimSA ( %sender );
EvoConsoleObsolete ( %sender, '.claimAdmin' );
case ".claimLease" : EvoConsoleClaimLease ( %sender );
case ".whois" : EvoConsoleWhois ( %sender, %Parameters );
case ".warn" : EvoConsoleWarnPlayer ( %sender, %Parameters );
case ".kick" : EvoConsoleKickPlayer ( %sender, %Parameters );
case ".ban" : EvoConsoleBanPlayer ( %sender, %Parameters );
case ".clanlock" : EvoConsoleClanLock ( %sender, %Parameters );
case ".nbr" : EvoConsoleNoBaseRape ( %sender, %Parameters );
case ".teamname" : EvoConsoleTeamName ( %sender, %Parameters );
default: messageClient( %sender, 'EvoCon',
'Error. Command unknown. Use \'.help\'' @
' to get a list of valid commands.' );
}
return;
}
Author