Modding Questions

Comments

• Krash

  1:41AM edited 1:46AM

  1: You can query the resource manager's file list through script using findFirstFile(pattern), findNextFile(pattern) and getFileCount(pattern). In the patched version, you can use multiple * wildcards, and multiple ? single unknown character matches, but in the standard version it's best to just use a single wildcard, i.e. audio/*.wav as your search pattern. The most common way you'll see this used in for enumeration is for (%file = findFirstFile(%pattern); %file !$= ""; %file = findNextFile(%pattern)) and a suuuuper basic way you'd use this to dump a list or cycle through waves could look something like:

  function findWaves()
  {
      %fo = new FileObject();
      %fo.openForWrite("wave.txt");
  
      $CurrentWave = 0;
      $TotalWaves = 0;
  
      %search = "*.wav";
      for (%wav = findFirstFile(%search); %wav !$= ""; %wav = findNextFile(%search))
      {
          %wavStart = strstr(%wav, "audio/");
          if (%wavStart != -1)
              %wav = getSubStr(%wav, %wavStart + 6, 1000);
  
          // if (alxGetWaveLen(%wav) == 0)
          //  continue;
  
          %fo.writeLine($TotalWaves TAB %wav);
  
          $Wave[$TotalWaves] = %wav;
          $TotalWaves++;
      }
  
      %fo.close();
      %fo.delete();
  
      GlobalActionMap.bind("keyboard", "ctrl ;", "playNextWave");
  }
  
  $WaveHandle = "";
  function playNextWave(%keydown)
  {
      if (!%keydown)
          return;
  
      alxStop($WaveHandle);
  
      %wav = $Wave[$CurrentWave];
  
      $WaveHandle = alxCreateSource(AudioChat, %wav);
      alxPlay($WaveHandle);
      echo("Playing wave file [" @ $CurrentWave @ "/" @ $TotalWaves - 1 @ "]" SPC %wav);
  
      if ($CurrentWave++ >= $TotalWaves)
          $CurrentWave = 0;
  }
  

  Of course, the utility in playing thousands of waves in sequence is a little limiting, so it'd be easier if they were in a GUI element or just played externally.

  
  

  2: %obj.dump(); will list the fields and methods attached to an object in the console

  
  

  3: If you want to change datablocks while ingame, the server needs to run %client.transmitDataBlocks(0); after every change to reset the entire set on any client you want to see these changes. You'll also want to make sure that this is avoided if the previous transmit hasn't completed, avoid changing the number of datablocks while running if you can, and to that point avoid referencing any datablock that the client wasn't made aware exists at an earlier point (they'll almost certainly crash if for example you created a new projectile datablock and fired it before they've been sent that datablock).

  
  

  4: Construction mod save files are essentially just scripts with a list of commands to create a set of static shapes and assign certain properties. The CCM/ACCM servers were typically actively managed by the admins with normal save files and a period of setup and chat commands run to keep events going. They weren't baked into the maps because you could set up multiple scenarios or just wipe and reset everything by loading a save at any point.

  The saves do have Construction-specific datablocks and function calls included, but generally speaking for a simple building using beams/pads there's nothing that'd prevent them from being included in any mission file, and they don't have to use any content that requires a download. There have been a few mods that've used Construction saves for one thing or another. It'd be a little more advanced to parse the save and convert them into interior blocks to be fully static and cast shadows, but that's also been done in the past.